* Library of Phototriac Optocoupler VOT8026
* Copyright VISHAY, Inc. 2018 All Rights Reserved.
*
.SUBCKT VOT8026 A C NC MT2 NC MT1  
X1         MT2 GATE MT1 VOT8026_tr
D1         10 C Demit 
V3         11 10 0Vdc
R3         A 11  1u TC=0,0 
R4	   0 NC 1MEG
C1	   0 NC 1u
G1         0 20 VALUE { If( abs(v(MT2) - v(MT1)) <= 5, I(v3)*1.03, 0 ) }
C2         0 20  10u
V4         20 21 0Vdc
R5         21 0  1
G_G2       0 GATE VALUE { i(V4) }
.MODEL Demit d
+IS=1e-15 RS=0.852101 N=1.51873 EG=1.3
+XTI=4 BV=6.04 IBV=5e-6 CJO=1e-11
+VJ=0.7 M=0.5 FC=0.5 TT=1e-09
+KF=0 AF=1
.ENDS
**********
.SUBCKT VOT8026_tr  1 2 3
*     TERMINALS: MT2 G MT1
QN1  5 4 3  NOUT OFF
QN2 11 6 7  NOUT OFF
QP1 6 11 3  POUT OFF
QP2  4 5 7  POUT OFF
DF  4  5  DZ
DR  6 11  DZ
RF  4 6  60000.00Meg
RT2 1 7  8.00
RH  7 6  3.75k
RGP 8 3  102
RG  2 8  998
RS  8 4  3.65k
DN  9 2  DIN
RN  9 3  855
GNN  6 7 9 3 24.3u
GNP  4 5 9 3 26.5u
DP 2 10  DIP
RP 10 3  110k
GP  7 6 10 3 20.5u
.MODEL DIP D ( IS=1.07f N=1.50 )
.MODEL DIN D ( IS=1.07f)
.MODEL DZ D ( IS=1.07f N=1.5 IBV=100u BV=800 )
.MODEL POUT PNP ( IS=1.07f BF=5 BR=.1 CJE=335f TF=0.850u )
.MODEL NOUT NPN  ( IS=1.07f BF=20 BR=.1 CJE=335f CJC=67.0f TF=0.0510u )
.ENDS
**************
**==================================================================*
* Note:                                                             *
* Although models can be a useful tool in evaluating device         *
* performance, they cannot model exact device performance           *
* under all conditions, nor are they intended to replace            *
* breadboarding for final verification!                             *
*                                                                   *
* Models provided by VISHAY Semiconductors GmbH are not             *
* as fully representing all of the specifications and operating     *
* characteristics of the semiconductor product to which the         *
* model relates.                                                    *
* The models describe the characteristics of typical devices.       *
* In all cases, the current data sheet information for a given      *
* device is the final design guideline and the only actual          *
* performance specification.                                        *
* VISHAY Semiconductors does not assume any liability arising       *
* from the model use. VISHAY Semiconductors reserves the right to   *
* change models without prior notice.				                *
**==================================================================*